ASP中在VBScript中使用類(lèi)的介紹說(shuō)明

本文主要跟大家一起分享的是ASP中在VBScript中使用類(lèi)的介紹說(shuō)明，希望能夠給大家?guī)��?lái)幫助或啟發(fā)。

前言
　　首先，在我進(jìn)入實(shí)質(zhì)性主題并解釋如何建立類(lèi)之前，我希望保證你知道“對(duì)象”。雖然你可以在程序中使用對(duì)象而不用知道其正確的規(guī)則，但我并不建議如此！對(duì)于對(duì)象的初學(xué)者，接下來(lái)的部分將讓你了解其概念及內(nèi)容。已經(jīng)了解面向?qū)ο缶幊蹋∣OP）的讀者可以跳過(guò)這章節(jié)。

　　導(dǎo)論
　　“對(duì)象是什么？”——對(duì)象通常代表某種實(shí)體，主要是一個(gè)變量和函數(shù)的集合。
　　“實(shí)體是什么？”——字面上說(shuō)，實(shí)體是一個(gè)“事物”，我的意思是一個(gè)概念或者任何一個(gè)物體。例如，一輛汽車(chē)是一個(gè)實(shí)體，因?yàn)樗�是一個(gè)物體。你公司銷(xiāo)售部門(mén)銷(xiāo)售產(chǎn)品也是一個(gè)實(shí)體，當(dāng)然，你也可以將其拆開(kāi)來(lái)看，銷(xiāo)售人員、客戶(hù)、產(chǎn)品等都是實(shí)體。

　　讓我們更深入的來(lái)看“銷(xiāo)售”這個(gè)實(shí)體（對(duì)象）。為了使你更準(zhǔn)確地有一個(gè)銷(xiāo)售的“映像”，你需要知道客戶(hù)買(mǎi)了什么，是哪個(gè)客戶(hù)，誰(shuí)是銷(xiāo)售人員等等……這看來(lái)是一個(gè)簡(jiǎn)單的事件，但假設(shè)所有信息是存儲(chǔ)在單獨(dú)的數(shù)據(jù)庫(kù)表中的，那么當(dāng)你需要獲得某個(gè)銷(xiāo)售過(guò)程所有相關(guān)信息時(shí)，你必須在你的數(shù)據(jù)庫(kù)中做多次獨(dú)立查詢(xún)，再將所有的數(shù)據(jù)集攏。有沒(méi)有更簡(jiǎn)便的辦法而一次獲得銷(xiāo)售的所有信息呢？“對(duì)象”。

　　在對(duì)象中，你可以植入代碼以從其他表中獲得數(shù)據(jù)，你也可以保存對(duì)象屬性的所有信息，這樣，你可以輕松地使用代碼管理你的銷(xiāo)售數(shù)據(jù)。例如：
'Open the database connection
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "MyDSN"

'Create the recordset object
Set objRS = Server.CreateObject("ADODB.Recordset")

'Define the SQL query
strComplexSQLQuery = "SELECT C.Name, S.Name FROM Customers C, " & _
"Salespeople S, Sales Sl WHERE Sl.CustomerID=C.ID AND " & _
"Sl.SalespersonID=S.ID AND Sl.ID=" & strIDOfThisSale & ";"

'Open the recordset
objRS.Open strComplexSQLQuery, objConn, adOpenForwardOnly, _
adLockReadOnly, adCmdText

'Take the customer and sales person names from the recordset
strCustomerName = objRS(0)
strSalesPersonName = objRS(1)

'Tidy up the objects
objRS.Close
objConn.Close
Set objRS = Nothing
Set objConn = Nothing

'Output the data
Response.Write "This sale was made by " & strSalesPersonName & _
" to " & strCustomerName

　　可以使用“對(duì)象”來(lái)替代：
'Create the "Sale" object
Set objSale = New Sale

'Lookup the correct sale
objSale.ID = strIDOfThisSale

'Output the data
Response.Write "This sale was made by " & objSale.SalesPersonName & _
" to " & objSale.CustomerName

'Tidy up the objects
objSale.Close
Set objSale = Nothing

　　如果你使用“Sale”對(duì)象做比打印更多的事，可以讓你省去很多的打字時(shí)間。

　　計(jì)算中，對(duì)象包括“屬性”和“方法”。屬性主要是儲(chǔ)存在對(duì)象中的一個(gè)變量，其用法與變量相同。唯一的區(qū)別在于參數(shù)賦值為：strMyVar = "This is a string variant", 而對(duì)象屬性為 objObject.Property="This is a string variant"。這點(diǎn)非常簡(jiǎn)單而有用處。方法可以理解為植入對(duì)象中的函數(shù)與過(guò)程，可以使用strMyVar = objObject.MethodName(strMyVar)來(lái)代替strMyVar =FunctionName(strMyVar)。寫(xiě)法不同，但功能相同。屬性的一個(gè)例子是對(duì)象Response中的ExpireAbsolute，Response.ExpiresAbsolute = CDate("1 September 1999")。方法的一個(gè)例子是對(duì)象Response中的Write方法，Response.Write "Hello world!"。

　　VBScript的一個(gè)新特性就是其可以創(chuàng)建新的對(duì)象而不需要求諸于花銷(xiāo)時(shí)間都極大的編譯器。我將向讀者展示如何創(chuàng)建對(duì)象的類(lèi)，并希望提供一個(gè)良好的開(kāi)端。

　　創(chuàng)建對(duì)象
　　在VBScript中創(chuàng)建對(duì)象類(lèi)型（類(lèi)）時(shí)，你首先要知道，這真的很容易！我在一個(gè)下午自學(xué)，只是閱讀了Microsof VB Script 的參考書(shū)，但必須承認(rèn)，這書(shū)不是最容易閱讀的文檔。

　　初學(xué)者需要安裝VBScript 5.0引擎，可以在microsoft's Scripting Site下載。

　　我們來(lái)看代碼。類(lèi)的定義與函數(shù)和子過(guò)程非常類(lèi)似。起始行為Class ，結(jié)尾是End Class，所有的對(duì)象定義寫(xiě)在中間部門(mén)。現(xiàn)在我們可以用所學(xué)的來(lái)建立第一個(gè)類(lèi)，不實(shí)現(xiàn)任何功能的類(lèi)。
Class 4GuysTestObject

End Class

　　這看上去不是那么回事，但當(dāng)你寫(xiě)入下面的代碼后，你將創(chuàng)建一個(gè)對(duì)象的實(shí)例：
Dim objTestObject
Set objTestObject = New 4GuysTestObject
Set objTestObject = Nothing

　　顯然，我們現(xiàn)在還不能用對(duì)象做任何事，現(xiàn)在我將解釋如何在對(duì)象中定義屬性和方法。

　　使用對(duì)象可以做的最基礎(chǔ)的，是建立一組數(shù)據(jù)。例如，假如要將時(shí)間、日期及視頻程序標(biāo)題建立在一起，你可以創(chuàng)建一個(gè)包含屬性“StartTime”， “ProgramDate”和“ProgramTitle”的對(duì)象。代碼如下：
Class TVProgram
Public StartTime
Public ProgramDate
Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"

Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate

　　代碼工作的方式是，我們定義StartTime，ProgramDate和ProgramTitle為類(lèi)TVProgram的屬性。這樣，這些屬性就像其他變量一樣來(lái)處理，沒(méi)有設(shè)置值則不會(huì)執(zhí)行代碼。屬性名字前的Public字段有其真實(shí)含義，而且非常重要。如果你不特指一個(gè)方法或?qū)傩詾閜ublic或private，系統(tǒng)默認(rèn)值為public，但最好養(yǎng)成定義任何值的良好書(shū)寫(xiě)習(xí)慣（也方便你之后自己的閱讀）。

　　上面程序的結(jié)果大致如下（決定于你的本地服務(wù)器配置）：The Jerry Springer Show is on at 5:30pm on 17/09/99.

　　我在英國(guó)，所以日期現(xiàn)實(shí)如上。不論你跑什么工程，它的效果都不錯(cuò)，但只有你開(kāi)始使用其他對(duì)象的功能，為你可能需要的所有信息和功能，創(chuàng)建一個(gè)完美的接口，以支持你所建對(duì)象包圍的實(shí)體，你才會(huì)體會(huì)到對(duì)象的真正實(shí)力。

　　現(xiàn)在，如果你不喜歡上面例子顯示日期的方法，而希望以同一種格式現(xiàn)實(shí)日期，也沒(méi)有不要在引用每個(gè)ProgramDate屬性時(shí)加FormatDateTime(),你只需要將此類(lèi)代碼植入屬性本身。

　　這樣需要用另一種方法定義屬性。同樣，我們將使用ProgramDate為外部可見(jiàn)屬性，但因?yàn)镻rogramDate屬性將成為一個(gè)函數(shù)而不是靜態(tài)值，我們將實(shí)際日期保存在另一個(gè)屬性中internal_ProgramDate。

Class TVProgram
Public StartTime

Public internal_ProgramDate

Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & _
" " & MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram

objTVShow.StartTime = CDate("17:30")
objTVShow.internal_ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"

Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　程序的結(jié)果如下：
The Jerry Springer Show is on at 5:30pm on 17 September 1999

　　我們來(lái)分析一下（2）中的程序：
Class TVProgram
Public StartTime
Public internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & _
" " & MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.internal_ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"
Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　當(dāng)調(diào)用對(duì)象的屬性ProgramDate時(shí)，實(shí)際上執(zhí)行了函數(shù)ProgramDate，即如上定義的函數(shù)，而很快你也將習(xí)慣這種在聲明部分使用Public或Private關(guān)鍵字的方式。關(guān)鍵字“Property”，告知了編譯器如同調(diào)用屬性一樣在外部調(diào)用函數(shù)。接著的“Get”，表明該函數(shù)是輸出還是獲得一個(gè)值。

　　Get的意思是“允許外部代碼去‘獲取’一個(gè)值”，與其類(lèi)似的關(guān)鍵字還有“Let”和“Set”，但這兩個(gè)比較復(fù)雜，因而我們以后再討論。

　　接下去的代碼看來(lái)有點(diǎn)難度的，給objectname.internal_ProgramDate賦值并通過(guò)objectname.ProgramDate來(lái)調(diào)用它。如果可以使用相同關(guān)鍵字同時(shí)為其賦值并獲得它的值不是更好嗎？當(dāng)然，那也可以。

　　如果定義Get和Let屬性的名稱(chēng)相同，可以將它們當(dāng)作對(duì)象相同的屬性，但這只限于它們定義了相同數(shù)量的成員。（以下代碼看來(lái)不太相同，僅作為實(shí)例參考）
Class TVProgram
Public StartTime
Public internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " _
& MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
internal_ProgramDate = CDate(varDateIn)
End Property

Public ProgramTitle
End Class

Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = "17 Sept 99"
objTVShow.ProgramTitle = "The Jerry Springer Show"
Response.Write objTVShow.ProgramTitle & " is on at " & _
objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

　　以上代碼中Let的聲明部分看來(lái)似乎是一個(gè)多余的元素，當(dāng)我第一次看到時(shí)研究了很長(zhǎng)時(shí)間。每次我使用“0”作為變量用在每個(gè)屬性上，我總是得到這個(gè)錯(cuò)誤信息，“元素?cái)?shù)量必須相等”。“它們確實(shí)相等！”抓狂之后，我回過(guò)頭去看程序才覺(jué)得自己的愚蠢�。海�

　　原因是，當(dāng)你試圖為ProgramDate賦值時(shí)，你會(huì)使用這樣一行程序：objTVShow.ProgramDate = dtmMyDate

　　為了方便，等號(hào)右邊的值（這里指dtmMyDate）作為了一個(gè)程元賦給了函數(shù)。因此編譯器可能會(huì)認(rèn)為在Get ProgramDate行有0程元，而Let ProgramDate卻多一個(gè)！分配的值總是被略過(guò)而作為屬性的最后一個(gè)程元，所以即使你使用其他程元，所賦的值總是作為最后一個(gè)程元。

　　現(xiàn)在看程序。無(wú)論通過(guò)ProgramDate設(shè)置日期為文本形式，還是用internal_ProgramDate譯成日期變量，程序都沒(méi)有問(wèn)題。但能不能只使用一個(gè)入口呢？

　　如果internal_ProgramDate只能在內(nèi)部有效，而使用Let ProgramDate檢查傳輸?shù)臄?shù)據(jù)類(lèi)型，我們就可以作出選擇。例如：
Class TVProgram
Public StartTime
Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " & _
MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
Else
'Place some error handling code in here.
End If
End Property

Public ProgramTitle
End Class

并同樣聲明StartTime屬性：
Class TVProgram
Private internal_StartTime
Public Property Get StartTime
StartTime = Hour(internal_StartTime) & ":" _
& Minute(internal_StartTime)
End Property

Public Property Let StartTime(ByVal varTimeIn)
If IsDate(varTimeIn) Then
internal_StartTime = varTimeIn
End If
End Property

Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " _
& MonthName(Month(internal_ProgramDate)) & _
" " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
End If
End Property

Public ProgramTitle
End Class
...
　　現(xiàn)在的代碼離我們想要的還是有些不太實(shí)用，我們將在其他頁(yè)使用類(lèi)TVProgram，因此最好將其獨(dú)立定義，以便所有也面都可以調(diào)用。我們將在第四部分討論這點(diǎn)。

　　現(xiàn)在的代碼離我們想要的還是有些不太實(shí)用，我們將在其他頁(yè)使用類(lèi)TVProgram，因此最好將其獨(dú)立定義，以便所有也面都可以調(diào)用。創(chuàng)建一個(gè)ASP頁(yè)面，并命名為T(mén)VProgramClass.asp，我們?cè)谄渲卸�義類(lèi)TVProgram。

--TVProgramClass.asp--
<%
Class TVProgram
Private internal_StartTime
Public Property Get StartTime
StartTime = Hour(internal_StartTime) & ":" & Minute(internal_StartTime)
End Property

Public Property Let StartTime(ByVal varTimeIn)
If IsDate(varTimeIn) Then
internal_StartTime = varTimeIn
End If
End Property

Private internal_ProgramDate
Public Property Get ProgramDate
ProgramDate = Day(internal_ProgramDate) & " " & MonthName(Month(internal_ProgramDate)) & " " & Year(internal_ProgramDate)
End Property

Public Property Let ProgramDate(ByVal varDateIn)
If IsDate(varDateIn) Then
internal_ProgramDate = varDateIn
End If
End Property

Public ProgramTitle
End Class
%>

　　這樣就可以在任何ASP中調(diào)用我們定義的類(lèi)了，語(yǔ)法如下：
<!-- #include virtual="TVProgramClass.asp" -->
<%
Dim objTVShow
Set objTVShow = New TVProgram
objTVShow.StartTime = CDate("17:30")
objTVShow.ProgramDate = DateSerial(1999,9,17)
objTVShow.ProgramTitle = "The Jerry Springer Show"
response.write objTVShow.ProgramTitle & " is on at " & objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."
%>

　　這里有一個(gè)建議。如果你重命名你的包含文件.asp，并保證所有重要代碼都在<% ... %>中，那么就算有人猜到了你包含文件的文件名，也沒(méi)辦法看見(jiàn)里面的內(nèi)容！